Fast random selection from short vectors in Julia

I have a simple function which appears at several places in my Julia code and is run millions of times inside a loop. The function essentially does rand([1,-1,im,-im]), that's, it picks one of four possible given values. I noticed that this function takes a substantial amount of time in my huge loop, so, I tried to write it in a slightly faster way like this:

function qpsk()
  temp1 = ifelse(rand(Bool), 1+0im, -1+0im)
  temp2 = ifelse(rand(Bool), 1+0im,  0+1im)
  temp1*temp2
end

Then, it is typically called like this:

sig = complex(zeros(N))
for i = 1:N
  sig[i] = qpsk()
end

Now, is there any way to further optimize this function, or use another faster method? Appreciate your help.

---

Comments on current answers:

The answer of @DanGetz (22 lines??) doesn't solve the problem, because at the moment, Julia is not as good at vectors as with explicit loops. Also, my simple, 1 line qpsk2(s) below, is about 2X faster than those "cryptic" 22 lines of code in the original answer by Dan (a vector is created, though, which adds more time).

But the question remains, why they didn't implement something like qpsk1 below? and why my original qpsk with branching is more than 3X faster than the straightforward qpsk4(s) below?

I added more versions below to guide the discussion if more experienced people like to jump in.

qpsk1(s) = s[1+(rand(Int8)&3)]          # Blazingly fast
qpsk2(s) = s[1+rand(Bool)+2rand(Bool)]  # Very fast
qpsk3(s) = s[rand(1:4,1)]               # Compiler issue here?
qpsk4(s) = s[rand(1:4)]                 # Why slow?
qpsk5(s) = rand([s])                    # Ridiculously slow!!
function test_orig(n)                   # Test qpsk(), very fast(branching!), why?
  for i = 1:n
    qpsk()
  end
end

using StaticArrays
function test(func, n)                  # Test all qpsk1 --> qpsk5
  s = SVector(1,-1,im,-im)
  for i=1:n
    func(s)
  end
end

@time test(qpsk1,10^8)  0.554994 seconds (5 allocations: 176 bytes)
@time test(qpsk2,10^8)  0.755286 seconds (5 allocations: 176 bytes)
@time test(qpsk3,10^8) 13.431529 seconds (400 M allocations: 26.822 GiB, 20.68% gc time)
@time test(qpsk4,10^8)  2.520085 seconds (5 allocations: 176 bytes)
@time test(qpsk5,10^8) 10.881852 seconds (200 M allocations: 20.862 GiB, 19.76% gc time)
@time test_orig(10^8)   0.771778 seconds (5 allocations: 176 bytes)
@time nqpsk2(10^8);     1.402830 seconds (9 allocations: 1.490 GiB, 6.39% gc time)